home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload Trio 2 / Shareware Overload Trio Volume 2 (Chestnut CD-ROM).ISO / dir40 / pc37042.zip / LIB / DTIME.ALC < prev    next >
Text File  |  1987-04-26  |  2KB  |  79 lines
  1.     TITLE 'DTIME - DISPLAY TIME IN UPPER LEFT CORNER'
  2. DTIME    CSECT
  3.     USING DTIME,R15
  4.     STM   R14,R4,SAVE
  5.     LR    R4,R15
  6.     DROP  R15
  7.     USING DTIME,R4
  8.     SVC   GETTIME  R0 = HOURS, MINUTES, SECONDS, 100TH SEC
  9.     ST    R0,WORK
  10.     SR    R0,R0
  11.     IC    R0,WORK   R0=HOURS
  12.     CVD   R0,PWORK
  13.     MVC   DWORK,=X'40212020'
  14.     ED    DWORK,PWORK+6
  15.     MVC   DHH,DWORK+2
  16.     IC    R0,WORK+1 R0=MINUTES
  17.     CVD   R0,PWORK
  18.     MVC   DWORK,=X'40212020'
  19.     ED    DWORK,PWORK+6
  20.     MVC   DMM,DWORK+2
  21.     IC    R0,WORK+2 R0=SECONDS
  22.     CVD   R0,PWORK
  23.     MVC   DWORK,=X'40212020'
  24.     ED    DWORK,PWORK+6
  25.     MVC   DSS,DWORK+2
  26.     MVI   DHH+2,C':'
  27.     MVI   DMM+2,C':'
  28.     LA    R1,DHHMMSS
  29.     LA    R2,8
  30.     SVC   EBCASC CONVERT TO ASCII
  31.     LA    R0,X'0300' READ CURSOR - ADV. MS-DOS PG 403
  32.     LA    R1,0      BX=0 PAGE #
  33.     SVC   VIDEO     GET CURSOR ROW,COL IN R15
  34.     ST    R15,SAVCUR
  35.     LA    R0,X'0200' SET CURSOR - ADV. MS-DOS PG 402
  36.     LA    R1,0                BX = 0 PAGE #
  37.     L     R15,=A(ROW*256+COL) DX = ROW,COL FOR CURSUR SET
  38.     SVC   VIDEO     SET CURSOR FOR DISPLAY
  39.     LA    R2,8
  40.     LA    R3,DHHMMSS
  41. LOOP     EQU   *
  42.     LA    R0,X'0E00'  WRITE TEXT IN TELETYPE MODE - ADV. MS-DOS PG 414
  43.     IC    R0,0(R3)    CHAR TO DISPLAY
  44.     LA    R3,1(R3)
  45.     LA    R1,0        PAGE 0
  46.     SVC   VIDEO
  47.     BCT   R2,LOOP
  48.     LA    R0,X'0200'  SET CURSOR
  49.     L     R15,SAVCUR
  50.     LA    R1,0
  51.     SVC   VIDEO       RESTORE CURSOR
  52.     LM    R14,R4,SAVE
  53.     BR    R14
  54. *
  55. * PC/370 SUPR STATE SVC'S
  56. *
  57. EBCASC   EQU   13   CONVERT TO ASCII
  58. GETTIME  EQU   18   GET TIME IN R0
  59. VIDEO    EQU   128+16 ROM BIOS VIDEO DRIVER (TECH. REF. A-48)
  60. SAVE     DC    9D'0'
  61. SAVCUR   DC    F'0'
  62. ROW      EQU   0    TOP LINE
  63. COL      EQU   72   LAST 8 COLUMNS
  64. R0       EQU   0
  65. R1       EQU   1
  66. R2       EQU   2
  67. R3       EQU   3
  68. R4       EQU   4 BASE
  69. R14      EQU   14
  70. R15      EQU   15
  71. DWORK    DC    CL4' Z99'
  72. WORK     DC    F'0'
  73. PWORK    DC    D'0'
  74. DHHMMSS  DS    0CL8
  75. DHH      DC    C'HH',C':'
  76. DMM      DC    C'MM',C':'
  77. DSS      DC    C'SS'
  78.     END
  79.